*update all

/*
stima su dataset abdata.dta
con IV, GMM, GMM_SYS
*/


*MAC:
cd /Users/mac/CAMILLA/Teaching/ADEIMF/July2017/ApplicationStata/

*cd e:\ADEIMF
clear
set more off
capture log close
log using lecture_panel_dynamic_application.log, replace

use abdata, clear
descr
tsset id year
xtdes, pattern(1000)
dtime year 1976 1984


tabulate year, generate(dum)
* generate dum1,dum2,...,dum9

*set matsize 7000
mata: mata query
*mata: mata set matacache 900
mata: mata set matafavor speed
*mata: mata set matafavor space


ssc install xtabond2
*\checking xtabond2 consistency and verifying not already installed...
*\installing into /Users/mac/Library/Application Support/Stata/ado/plus/...
*\installation complete.

ssc install ivreg2
ssc install abar

* 3.1. OLS estimates: Arellano-Bond (1991), Table 5, col. (g), p. 292
**************************************************************************************
reg n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, cluster(id)
*reg n l(1/2).n l(0/1).w l(0/2).(k ys) dum1-dum9, cluster(id)
abar, lags(2)

ivreg2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, cluster(id) small
abar, lags(2)

ivreg2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, cluster(id)
abar, lags(2)

xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(level)) arle robust 
predict yhat
qui corr yhat n if e(sample)
scalar XTAB_r2=r(rho)^2
drop yhat
di XTAB_r2

* 3.2. Within estimates: Arellano-Bond (1991), Table 5, col. (h), p. 292
************************************************************************
xtreg n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, fe cluster(id)

*qui within id n nL1 nL2 w wL1 k kL1 kL2 ys ysL1 ysL2 tau1979 tau1980 tau1981 tau1982 tau1983 tau1984 if nL2!=.
qui within id n nL1 nL2 w wL1 k kL1 kL2 ys ysL1 ysL2 tau1979 tau1980 tau1981 tau1982 tau1983 tau1984 if e(sample)

ivreg2 n_WD nL1_WD nL2_WD w_WD wL1_WD k_WD kL1_WD kL2_WD ys_WD ysL1_WD ysL2_WD tau1979_WD-tau1984_WD, small noconstant cluster(id)

ivreg2 n_WD nL1_WD nL2_WD w_WD wL1_WD k_WD kL1_WD kL2_WD ys_WD ysL1_WD ysL2_WD tau1979_WD-tau1984_WD, noconstant cluster(id)

xtabond2 n_WD nL1_WD nL2_WD w_WD wL1_WD k_WD kL1_WD kL2_WD ys_WD ysL1_WD ysL2_WD tau1979_WD-tau1984_WD, iv(nL1_WD nL2_WD w_WD wL1_WD k_WD kL1_WD kL2_WD ys_WD ysL1_WD ysL2_WD tau1979_WD-tau1984_WD, eq(level)) noconstant arle robust
predict yhat
qui corr yhat n_WD if e(sample)
scalar XTAB_r2=r(rho)^2
drop yhat
di XTAB_r2

* 3.3. First-differences estimates
**********************************
xtivreg n (l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984 = l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984), fd noconst

ivreg2 d.n dl.n dl2.n d.w dl.w d.k dl.k dl2.k d.ys dl.ys dl2.ys d.(tau1979 tau1980 tau1981 tau1982 tau1983 tau1984), noconst small
abar, lags(2)

ivreg2 d.n dl.n dl2.n d.w dl.w d.k dl.k dl2.k d.ys dl.ys dl2.ys d.(tau1979 tau1980 tau1981 tau1982 tau1983 tau1984), noconst cluster(id)
abar, lags(2)

xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) noleveleq robust
predict yhat
qui corr yhat d.n if e(sample)
scalar XTAB_r2_D=r(rho)^2
qui corr yhat n if e(sample)
scalar XTAB_r2_L=r(rho)^2
drop yhat
di XTAB_r2_D
di XTAB_r2_L

* 3.4. Anderson-Hsiao (1981)  estimates with IV in differences: Arellano-Bond (1991), Table 5, col. (e), p. 292
***************************************************************************************************************
xtivreg n (l.n l2.n l(0/1).w l(0/2).(k ys) tau1980-tau1984 = l3.n l2.n l(0/1).w l(0/2).(k ys) tau1980-tau1984), fd noconst

xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1980-tau1984, iv(l(2/3).n l(0/1).w l(0/2).(k ys) tau1980-tau1984, eq(diff)) robust noleveleq

* 3.5. Anderson-Hsiao (1982)  estimates with IV in levels: Arellano-Bond (1991), Table 5, col. (f), p. 292
*********************************************************************************************************
facum id n
xtivreg n (l.n l2.n l(0/1).w l(0/2).(k ys) tau1979-tau1984 = l2.cumnl l2.n l(0/1).w l(0/2).(k ys) tau1979-tau1984), noconst fd 

xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l2.n l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) iv(l3.n , eq(diff) passthru) robust noleveleq

* 3.6. GMM-dif estimates: Arellano-Bond (1991), Table 4, col. (a1) (a2), p. 290
*******************************************************************************
xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 .) eq(diff)) noleveleq h(2)
xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 .) eq(diff)) robust noleveleq h(2)

xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 .) eq(diff)) robust noleveleq h(2)  twostep
xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 .) eq(diff)) noleveleq h(2)  twostep

** NOTE
xtabond2 n l(1/2).n l(0/1).w l(0/2).(k ys) tau1979-tau1984, iv(l(0/1).w l(0/2).(k ys) tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 2) eq(diff)) gmm(n, laglimits(3 .) eq(diff)) noleveleq h(2) robust


* 3.7. GMM-dif estimates: Arellano-Bond (1991), Table 4, col. (b) (c), p. 290
*********************************************************************************
xtabond2 n l(1/2).n l(0/1).w k l(0/2).ys tau1979-tau1984, iv(l(0/1).w k l(0/2).ys tau1979-tau1984, eq(diff)) gmm(n, laglimits(2 .) eq(diff)) noleveleq h(2)  twostep

xtabond2 n l(1/2).n l(0/1).w k l(0/1).ys tau1979-tau1984, iv(l(0/1).ys tau1979-tau1984, eq(diff)) gmm(n, lag(2 .) eq(diff)) gmm(w k, lag(2 3) eq(diff)) noleveleq h(2) twostep 

* 3.8. GMM-dif and GMM-sys estimates: Blundell-Bond (1998), Table 4, col. III and IV, p. 137
********************************************************************************************
xtabond2 n l.n l(0/1).(w k) tau1978-tau1984, iv(tau1978-tau1984, eq(diff)) gmm(n w k, lag(2 .) eq(diff)) noleveleq h(2) robust

xtabond2 n l.n l(0/1).(w k) tau1978-tau1984, iv(tau1978-tau1984, eq(both)) gmm(n w k, lag(2 .) eq(both)) h(1) robust
xtabond2 n l.n l(0/1).(w k) tau1978-tau1984, iv(tau1978-tau1984, eq(both)) gmm(n w k, lag(2 .) eq(both)) h(2) robust
xtabond2 n l.n l(0/1).(w k) tau1978-tau1984, iv(tau1978-tau1984, eq(both)) gmm(n w k, lag(2 .) eq(both)) h(3) robust