*cd e:\ADEIMF

clear
*clear matrix
set more off
capture log close
set linesize 255
log using lecture_dynpanel.log, replace


use R_euroarea.dta, clear
tsset cod anno
dtime anno

****************
* STATIC MODEL *
****************
* individual heterogeneity dealt with by using within
xtreg tint dlpc, fe
est store FEstat
xtreg tint dlpc tau1982-tau1998, fe
est store FEstatTD
* individual heterogeneity dealt with by using first-differences
reg d.tint d.dlpc, noconst
est store FDstat
reg d.tint d.dlpc d.(tau1982-tau1998), noconst
est store FDstatTD

********************
* DYNAMIC MODEL ****
********************
*ssc install xtabond2, replace
ssc install estout, replace
* individual heterogeneity dealt with by using within
* ARDL
xtreg tint dlpc l.tint l.dlpc, fe
est store FEdyn
* ECM reparametrization
xtreg d.tint d.dlpc l.tint l.dlpc, fe
est store FEdynECM
xtreg d.tint d.dlpc l.tint l.dlpc tau1982-tau1998, fe
est store FEdynECMTD

* individual heterogeneity dealt with by using first-differences
* ARDL
reg d.tint d.dlpc ld.tint ld.dlpc, noconst
est store FDdyn
* ECM reparametrization
reg dd.tint dd.dlpc ld.tint ld.dlpc, noconst
est store FDdynECM
reg dd.tint dd.dlpc ld.tint ld.dlpc d.(tau1982-tau1998), noconst
est store FDdynECMTD

* Anderson-Hsiao IV estimation method:
xtabond2 d.tint d.dlpc l.tint l.dlpc tau1982-tau1998, iv(tau1982-tau1998, eq(diff)) iv(d.dlpc l.dlpc, eq(diff)) iv(l2.tint, passthru mz eq(diff)) h(1) nolev ar(3)
est store AH

********************
* xtabond2 command: first model specification: d.tint d.dlpc l.tint l.dlpc tau1982-tau1998; 
*exogenous variables iv(tau1982-tau1998, eq(diff)); 
*endogenous variables iv(d.dlpc l.dlpc, eq(diff)); 
*instruments: iv(d.dlpc l.dlpc, eq(diff)) iv(l2.tint, passthru mz eq(diff)) h(1) nolev ar(3)
*passthru mz: leave IV in levels for first differences eqs.
*h(1) for varcov matrix 
********************

* Arellano Bond GMM estimation method:
xtabond2 d.tint d.dlpc l.tint l.dlpc tau1982-tau1998, iv(tau1982-tau1998, eq(diff)) iv(d.dlpc l.dlpc, eq(diff)) gmm(tint, lag(2 .) eq(diff))  h(2)  nolev ar(3)
est store AB

********************
* xtabond2 command: first model specification: d.tint d.dlpc l.tint l.dlpc tau1982-tau1998; 
*exogenous variables iv(tau1982-tau1998, eq(diff)); 
*endogenous variables iv(d.dlpc l.dlpc, eq(diff)); 
*instruments: gmm(tint, lag(2 .) eq(diff))  h(2)  nolev ar(3)
*lag(2 .): means lag 2 and 1 (two lags for first difference in dependent variable tint)
*h(2) for varcov matrix 
********************